# no need for translation 
# recursief -> rangnummer
!set n=$teller
!if $graad =0
    R=$teller
!else
    R=$graad
!endif        

nivo_title=!record 26 of lang/remarks.$taal
# Omrekenen van Recursie formule naar Rangnummmer formule
multiplechoice=0                                                                                               
keuze=!randitem 1,2                                                                                          
!if $keuze=1
    TYPE=!record 12 of lang/remarks.$taal
    # Meetkundige
    NTYPE=!record 13 of lang/remarks.$taal
    # Rekenkundige
!else
    TYPE=!record 13 of lang/remarks.$taal
    # Rekenkundige
    NTYPE=!record 12 of lang/remarks.$taal
    # Meetkundige
!endif

!if $R>0
    bewerking=nivo/bewerking4.proc
    !if $keuze=2
	a=!randint 1,20
	r=!randitem 2,3,4,5,6,7,8,9
        ss=!record 27 of lang/remarks.$taal
	somtekst$n=$ss
	# Gegeven de Recursie formule van een $TYPE rij:<p align="center">\
	# U<sub>n</sub>=U<sub>n-1</sub> + $r <br> met U<sub>1</sub>=$a</p>\
	# Geef de Rangnummer formule van deze rij.
	
	GOED$n=$a+$r*(n-1)
	formule=U<sub>n</sub>=$a+$r(n-1)
	!for p=1 to 5
	    U=$[$a+$r*($p-1)]
	    goed$n=!append line <li>U<sub>$p</sub>=$U</ll> to $(goed$n)
	!next p
    !else
	a=!randint 1,20
	r=!randitem 2,3,4,5,6,7,8,9
	ss=!record 28 of lang/remarks.$taal
	somtekst$n=$ss
	# Gegeven de Recursie formule van een $TYPE rij:<p align="center">\
	# U<sub>n</sub>=$r&times;U<sub>n-1</sub><br> met U<sub>1</sub>=$a</p>\
	# Geef de Rangnummer formule van deze rij.
	
	GOED$n=$a*$r^(n-1)
	!for p=1 to 5
	    U=$[$a*$r^($p-1)]
	    goed$n=!append line <li>U<sub>$p</sub>=$U</ll> to $(goed$n)
	!next p
	formule=U<sub>n</sub>=$a&times;$r<sup>n-1</sup>
    !endif
    ss=!record 29 of lang/remarks.$taal
    # Het is een $TYPE rij...dus de Rangnummer formule is: $formule 
    goed$n=<ul>$(goed$n)</ul>$ss
    !exit
!endif
